1.3 驅動器信息

取得某個驅動器對象可以使用FSO對象的GetDrive方法，參數是盤符，可以帶冒號和反斜杠，如“C”“C:”“C:\”。舉例如下：

Set drive = fso.GetDrive("C:\")

Drive對象的屬性列表如表1-3所示。

表1-3 Drive對象的屬性

讀取驅動器信息之前，應該先判斷驅動器是否存在，然后再判斷驅動器是否準備就緒。第一步可以使用FSO對象的DriveExists方法來判斷，第二步可以使用Drive對象的IsReady屬性來判斷。

下面看一個讀取C盤屬性的例子。

Drive.asp

<%@codepage=936%>
<! --#include File="fso_function.asp" -->
<%
Response.Charset = "GBK"

drivePath = "c:\"
Set fso = CreateObject("Scripting.FileSystemObject")

'判斷驅動器是否存在
If fso.DriveExists(drivePath) Then
    Set drive = fso.GetDrive(drivePath) '取得drive對象

    '判斷是否準備就緒
    If drive.IsReady Then
            Response.Write "空間：" & drive.AvailableSpace & "字節<br>"
            Response.Write "驅動器字符：" & drive.DriveLetter & "<br>"
            Response.Write "驅動器類型：" & GetDriveTypeName(drive.DriveType) & "<br>"
            Response.Write "文件系統：" & drive.FileSystem & "<br>"
            Response.Write "剩余空間：" & drive.FreeSpace & "字節<br>"
            Response.Write "路徑：" & drive.Path & "<br>"
            Response.Write "根目錄：" & drive.RootFolder & "<br>"
            Response.Write "序列號：" & drive.SerialNumber & "<br>"
            Response.Write "共享名：" & drive.ShareName & "<br>"
            Response.Write "空間大小：" & drive.TotalSize & "字節<br>"
            Response.Write "卷標：" & drive.VolumeName & "<br>"
    Else
            Response.Write "驅動器沒有準備好。"
    End If
Else
    Response.Write "驅動器不存在。"
End If
Set fso = Nothing
%>

運行結果如圖1-2所示。

圖1-2 讀取C盤屬性