1.5.1 文件夾屬性

Folder對(duì)象的屬性如表1-5所示。

下例將輸出C:\Program Files\Common Files\這個(gè)文件夾的各種屬性。

Folder.asp

<%@codepage=936%>
<%
Response.Charset = "GBK"

folderPath = "C:\Program Files\Common Files\"
Set fso = CreateObject("Scripting.FileSystemObject")
'判斷文件夾是否存在
If fso.FolderExists(folderPath) Then
    Set folder = fso.GetFolder(folderPath)  '取得Folder對(duì)象

    '輸出各種屬性
    Response.Write "屬性：" & folder.Attributes &"<br>"
    Response.Write "創(chuàng)建時(shí)間：" & folder.DateCreated &"<br>"
    Response.Write "上次訪問時(shí)間：" & folder.DateLastAccessed & "<br>"
    Response.Write "上次修改時(shí)間：" & folder.DateLastModified & "<br>"
    Response.Write "所在驅(qū)動(dòng)器：" & folder.Drive &"<br>"
    Response.Write "根目錄：" & folder.IsRootFolder &"<br>"
    Response.Write "文件夾名：" & folder.Name &"<br>"
    Response.Write "父文件夾：" & folder.ParentFolder &"<br>"
    Response.Write "路徑：" & folder.Path &"<br>"
    Response.Write "短文件夾名：" & folder.ShortName &"<br>"
    Response.Write "短路徑：" & folder.ShortPath &"<br>"
    Response.Write "大小：" & folder.Size &"字節(jié)<br>"
    Response.Write "類型：" & folder.Type & "<br>"
Else
    Response.Write "文件夾不存在。"
End If
Set fso = Nothing
%>

運(yùn)行結(jié)果如圖1-4所示。

Attributes屬性的可選值如表1-6所示。

實(shí)際上，這個(gè)列表是文件夾和文件共用的。

一個(gè)對(duì)象的Attributes屬性可以是列表中值的組合。如只讀文件夾是17（1+16），系統(tǒng)文件夾是20（4+16），只讀隱藏系統(tǒng)文件夾是23（1+2+4+16），以此類推。

判斷或去除某個(gè)Attributes屬性時(shí)，建議使用邏輯運(yùn)算符。如判斷對(duì)象是否是隱藏的，可以使用AND運(yùn)算符進(jìn)行判斷。

If folder.Attributes AND 2 Then
    Response.Write "是隱藏的"
End If

如果想將對(duì)象變?yōu)椴浑[藏，可以使用XOR運(yùn)算符。

folder.Attributes = folder.Attributes XOR 2

表1-6中的讀寫是什么意思呢？以Attributes值為16為例，如果一個(gè)對(duì)象的值是16 （也可能是17、18、19等），那么表示它是一個(gè)文件夾，這個(gè)事實(shí)是不允許更改的，所以這個(gè)值是只讀的。換句話說，16這個(gè)值始終是與文件夾綁定的，不能去掉它，一個(gè)文件夾的Attributes屬性一定大于等于16。